Field Rotation Issues

       

10 ' FIELD ROTATION

20 '

30 PI=ATN(1)*4: DR=PI/180: RD=180/PI

40 INPUT "Observer's latitude (deg) ";LA

50 LA=LA*DR: CL=COS(LA): SL=SIN(LA)

60 INPUT "Day of the month (1-31)";J

70 INPUT "Month (1-12) ";M

80 INPUT "Right ascension (h,m) ";H5,M5

90 INPUT "Declination (deg) ";DE

100 AD=H5+M5/60: DE=DE*DR: ' Hours and radians

110 SD=SIN(DE): CD=COS(DE): TD=SD/CD

120 GOSUB 650: PRINT

130 INPUT "From (h,m): ";H1,M1

140 T1=H1+M1/60: ' Starting time (hours)

150 INPUT "To (h,m): ";H2,M2

160 T2=H2+M2/60: ' Ending time (hours)

170 IF T2<T1 THEN T2=T2+24: ' If crossing midnight

180 PRINT

190 PRINT "Positive rotation rates are clockwise:"

200 DU=60*(T2-T1)+.01: ' Exposure duration (min.)

210 FOR T=0 TO DU STEP 1

220 LT=T1+T/60: ' Local mean time (hours)

230 GOSUB 520: A=AZ

240 DD=SIN(AH): DS=(SL/CL)*CD-SD*CH

250 IF DS<>0 THEN 270

260 C=SGN(DD)*PI/2: GOTO 280: ' In case DS=0

270 C=ATN(DD/DS): IF DS<0 THEN C=C+PI

280 Q=C*RD: ' Parallactic angle in degrees

290 IF T<>0 THEN 310

300 Q0=Q: Q1=Q: ' Save initial value of Q

310 XX=Q-Q1: XT=Q-Q0

320 IF ABS(XX)<=180 THEN 340

330 XX=XX-360*SGN(XX): Q=Q-360*SGN(Q)

340 Q1=Q

350 IF T<>0 THEN GOSUB 470

360 IF T=0 THEN GOSUB 700

370 IF XT>MX THEN MX=XT

380 IF XT<MN THEN MN=XT

390 NEXT

400 PRINT: PRINT "Cumulative field rotation: ";

410 PRINT USING "####.## deg";MX-MN

420 PRINT

430 PRINT USING "Start alt. ### Az. ###";H0;A0

440 PRINT USING "Ending alt. ### Az. ###";H;A

450 END

460 '

470 IF LT>=24 THEN LT=LT-24

480 PRINT USING " ##h ##m ";INT(LT);(LT-INT(LT))*60;

490 PRINT USING " Rotation +###.## deg/min ";XX

500 RETURN

510 ' Compute hour angle, altitude, and azimuth

520 HD=15*(1.002737*LT+ST-AD): ' Hour angle (deg)

530 IF HD>=360 THEN HD=HD-360

540 AH=HD*DR: CH=COS(AH): SA=SL*SD+CL*CD*CH

550 IF ABS(SA)<1 THEN 580

560 IF ABS(SA)>1 THEN SA=1*SGN(SA)

570 H=SA*90: GOTO 590: ' If zenith or nadir

580 H=ATN(SA/SQR(1-SA*SA))*RD: ' Altitude (degrees)

590 A1=SIN(AH): A2=CH*SL-TD*CL: IF A2<>0 THEN 610

600 AZ=SGN(A1)*PI/2: GOTO 620: ' Special case A2=0

610 AZ=ATN(A1/A2): IF A2<0 THEN AZ=AZ+PI

620 AZ=AZ*RD+180: ' Azimuth in degrees from north

630 IF AZ>=360 THEN AZ=AZ-360

640 RETURN

650 ' Find approx. sidereal time at midnight

660 N=INT(275*M/9)-2*INT((M+9)/12)+J-30

670 ST=(6.61+.06571*N)/24

680 ST=(ST-INT(ST))*24: ' Express in hours

690 RETURN

700 ' Initialize values

710 MX=XX: MN=XX: A0=A: H0=H

720 RETURN

800 '

810 ' ROTATE.BAS -- This program by Alphonse

820 ' Pouplier computes the rate at which

830 ' the field will rotate for a telescope

840 ' whose polar axis is misaligned on the

850 ' celestial pole. This subject is discussed

860 ' in detail in Sky & Telescope, September

870 ' 1992, page 318. 

Subject: Field Rotation from Misalignmentƒƒ

From: James W. Burrows <burrjawearthlink.net>

Chris Vedeler <cvedelerix.netcom.com> wrote:
> It is hard to imagine that being 2.5 minutes of arc from the true pole
> could cause field rotation enough to show up on a 1 hour exposure at
> f/10 on 35mm film.
> Is there a way to calculate field rotation given where in the sky you
> are photographing and how far off your polar alignment is?

POLAR mode field rotation rate:

W*dD*cos(H - Hp)cosD with:

W = Earth sidereal angular rate (15.041 deg/h = 72.9 urad/s),

D, H = telescope pointing angle: declination, hour angle,

dD, Hp = polar alignment error: declination (small, rad), hour angle

It's greatest at the intersection of the equator & the hour circle through the telescope polar axis.

Effect of field rotation.

Assume 35 mm film (24x36 mm (quick run down stairs and measure negative) and 100 lines/mm. Assuming the worst field rotation from 1 deg (.017 rad) polar misalignment (and optical axis centered on the film), the time to move one line at the corner of the film is:

.02/sqrt(24^2 + 36^2)/72.9E-6/.017 = 373 s

Subject: Field Rotation Calculator Spread Sheet 

From: Chris Vedeler <cvedelerix.netcom.com>

I have made a Field Rotation Calculator that seems to give all the answers I would expect from the data I have put through it. It will tell you how many arc seconds of field rotation you can expect for a given polar alignment error, exposure, declination, film size, and focal length.

It is an MS Excel 5.0 document. If you want a copy e-mail me at my home address: <cvedelerix.netcom.com> and I will email it off to you.

Subject: Movement of a Star in the Image Field Due to Rotation  

From: Doc G

Visit Doc G's website for more of his research.

The issue of the actual linear motion of a star in the image plane of a polar mounted telescope is considered here. The motion of a star in the image field depends upon three factors. One is the amount of actual field rotation which is caused by the fact that the RA axis of the telescope is not exactly aligned with the earth's axis. Call this the angle of misalignment, A. This misalignment causes a rotation rate, R. The rotation rate is 4.37E-3 radians per minute times the number of degrees of misalignment.

That is R= 4.37E-3 * A Where A is in degrees of misalignment.

The actual number of minutes of exposure possible for a given allowed drift amount, d, is dependent upon the distance between the guide star, which is the center of rotation, and the star of concern. Call this distance, D. D is the actual distance measured at the imaging plane.

It can be found in two ways. The simplest is when the guide star and the star of concern are both on the field being imaged. If the guide star is in the center of the image for a 35mm size image, the most distant star is in the cormer which is 21.5 mm distant. For a CCD chip of 400 size, the distance from the center to the corner is 4.15 mm. If the guide star is outside the image frame its effective distance must be calculated from the angular separation of the two stars and the focal length of the telescope. For example, with a 1200 mm telescope and a separation of 1 degree, the star separation in the image plane is 1200 times 0.017 or 20.4 mm.

The actual number if minutes of exposure allowed to reach the limits described is then.

Minutes of exposure = ( d/D ) * A * 13E3

For example with 1 degree of misalignment 0.01 mm of star trail, and a distance of half the diagonal of a 35 mm frame, we get:

Minutes = 0.01/21.5 * 1 * 13E3 = 6 minutes

For the same situation with a size 400 chip (416 or ST-7) we get,

Minutes = 0.01/4.15 * 1 * 13E3 = 31.3 minutes

For the same CCD chip conditions but with the guide telescope pointed 1 degree off the axis of the center of the chip and using a 1200 mm telescope, we get, the effective distance, D = 21 mm between the guide star and the center of the chip. Then the center of the chip will move the specified amount of 0.01 mm in a time given by,

Minutes = 0.01/21 * 1 * 13E3 = 6.2 minutes

Thus we see that a significant penalty is paid by guiding too far away from the imaging chip.